#define POWER_CTL      10  // Power switch
#define JL_CLK         11  // goes to USBDP
#define JL_DAT         12  // goes to USBDM

/*========================================================*/

bool powered_on;

void power_off(void) {
  digitalWrite(POWER_CTL, LOW);
  powered_on = false;
}

void power_on(void) {
  if (powered_on) {
    power_off();
    delay(100);
  }

  digitalWrite(POWER_CTL, HIGH);
  powered_on = true;
}

/*========================================================*/

enum {
  ISP_CMD_READ_BUFF     = 0x07, // Read temp buffer
  ISP_CMD_RAM_NEXT      = 0x12, // Advance to a next RAM word
  ISP_CMD_ECHO          = 0x14, // Echo back
  ISP_CMD_RAM_WRITE     = 0x18, // Write a word into RAM
  ISP_CMD_START_CPU     = 0x19, // Start the CPU
  ISP_CMD_CHIP_ID2      = 0x1E, // Read another chip ID (minor?)
  ISP_CMD_CHIP_ID       = 0x1F, // Read chip ID (major?)
};


void isp_init(void) {
  digitalWrite(JL_CLK, LOW);
  pinMode(JL_CLK, OUTPUT);
  pinMode(JL_DAT, INPUT);
}

void isp_deinit(void) {
  pinMode(JL_CLK, INPUT);
  pinMode(JL_DAT, INPUT);
}

void isp_sendb(uint8_t val) {
  pinMode(JL_DAT, OUTPUT);

  for (uint8_t mask = 0x80; mask; mask >>= 1) {
    digitalWrite(JL_DAT, val & mask ? HIGH:LOW);
    digitalWrite(JL_CLK, HIGH);
    delayMicroseconds(5);
    digitalWrite(JL_CLK, LOW);
    delayMicroseconds(5);
  }
}

uint8_t isp_recvb() {
  uint8_t val = 0;
  
  pinMode(JL_DAT, INPUT);

  for (uint8_t mask = 0x80; mask; mask >>= 1) {
    digitalWrite(JL_CLK, HIGH);
    delayMicroseconds(5);
    digitalWrite(JL_CLK, LOW);
    if (digitalRead(JL_DAT)) val |= mask;
    delayMicroseconds(5);
  }

  return val;
}

/*
 * MODE_DET key for entering the ISP mode
 */
void isp_modedet_key(char type) {
  isp_sendb(0xFF);

  switch (type) {
  case 0: isp_sendb(0x6A); isp_sendb(0x58);                  break;  // 6A58    - BR17 and older
  case 1: isp_sendb(0x81); isp_sendb(0xF9); isp_sendb(0xA8); break;  // 81F9A8  - BR20
  case 2: isp_sendb(0x01); isp_sendb(0xF9); isp_sendb(0xA8); break;  // 01F9A8  - BR21 and newer
  }
}

/*
 * An ISP init sequence
 */
void isp_initseq() {
  isp_sendb(0x00);
  isp_sendb(0x00);
  isp_sendb(0x00);
  isp_sendb(0x00);
  isp_sendb(0x00);
  isp_sendb(0xA8);
  isp_sendb(0x00);
  isp_sendb(0x00);
}

/*
 * Basic commands (taking no data)
 */
void isp_cmd_exec(char op) {
  /* Ooooo... ........ */
  isp_sendb(op << 3);
  isp_sendb(0);
}

/*
 * 1-byte operand/response commands
 */
void isp_cmd_send1(char op, uint8_t val) {
  /* OooooVvv vvvvv... */
  isp_sendb((op << 3) | (val >> 5));
  isp_sendb(val << 3);
}

/*
 * 4-byte operand/response commands
 */
uint32_t isp_cmd_recv4(char op) {
  /* Ooooo... | Aaaaaaaa Bbbbbbbb Cccccccc Dddddddd */
  uint32_t tmp;
  isp_sendb(op << 3);
  tmp  = (long)isp_recvb() << 24;
  tmp |= (long)isp_recvb() << 16;
  tmp |= (long)isp_recvb() << 8;
  tmp |= (long)isp_recvb() << 0;
  return tmp;
}

/*========================================================*/

void setup() {
  digitalWrite(POWER_CTL, LOW);
  pinMode(POWER_CTL, OUTPUT);
  pinMode(JL_CLK, INPUT);
  pinMode(JL_DAT, INPUT);

  Serial.begin(19200);
}

void loop() {
  power_on();
  isp_init();

  for (int i = 0; i < 10; i++) {
    isp_modedet_key(2);
    isp_initseq();

    uint32_t recv;

    isp_cmd_exec(ISP_CMD_CHIP_ID);
    recv = isp_cmd_recv4(ISP_CMD_READ_BUFF);

    if ((recv & ~0xFF) == 0 && (recv & 0xFF) != 0) {
      Serial.print("Got the chip ID: ");
      Serial.print(recv, HEX);

      Serial.print('/');

      isp_cmd_exec(ISP_CMD_CHIP_ID2);
      recv = isp_cmd_recv4(ISP_CMD_READ_BUFF);
      Serial.println(recv, HEX);
      break;
    }
  }

  isp_deinit();
}